#!/usr/local/bin/perl
#
#         File:	bail-out.pl
#     Abstract:	Simulate the various ways a Unix process can exit or die.
#       Author:	Bill.Costa@unh.edu -- CIS Network Information Services
#         Date:	12-OCT-2000
#
#  I created this program for testing exit and error handling of
#  scripts that I write.  This is suppose to cover all the ways I
#  could find that a Unix process can become an ex-process.  If you
#  know of any other ways -- other than the halting the CPU or killing
#  shell, let me know!
#
#==============================================================================

    my $ownName = $0;			# So we can say who we are.
    $ownName =~ s{.*/}{};

    my $op;				# Method of exit.
    my $code;				# Code to use with that method.
    my $usrMsg;				# Print this to STDOUT or STDERR.


#------------------------------------------------------------------------------
#  Subroutines	---------------------------------------------------------------
#------------------------------------------------------------------------------

sub showSigCodes ()

# These are different for different flavors of Unix.  For the codes 
# on any given system, try any one of:
#
#      kill -l
#      trap -l
#      man 4 signal
#      more /usr/include/signal.h
#
# These are for Redhat Linux.

{
            print(STDERR <<CODES);

      Code Name         Function
      ---- ----------   --------------------------------
         1 SIGHUP       Hangup (POSIX).
         2 SIGINT       Interrupt (ANSI).
         3 SIGQUIT      Quit (POSIX).
         4 SIGILL       Illegal instruction (ANSI).
         5 SIGTRAP      Trace trap (POSIX).
         6 SIGABRT      Abort (ANSI).
         6 SIGIOT       IOT trap (4.2 BSD).
         7 SIGBUS       BUS error (4.2 BSD).
         8 SIGFPE       Floating-point exception (ANSI).
         9 SIGKILL      Kill, unblockable (POSIX).
        10 SIGUSR1      User-defined signal 1 (POSIX).
        11 SIGSEGV      Segmentation violation (ANSI).
        12 SIGUSR2      User-defined signal 2 (POSIX).
        13 SIGPIPE      Broken pipe (POSIX).
        14 SIGALRM      Alarm clock (POSIX).
        15 SIGTERM      Termination (ANSI).
        16 SIGSTKFLT    Stack fault.
        17 SIGCLD       Same as SIGCHLD (System V).
        17 SIGCHLD      Child status has changed (POSIX).
        18 SIGCONT      Continue (POSIX).
        19 SIGSTOP      Stop, unblockable (POSIX).
        20 SIGTSTP      Keyboard stop (POSIX).
        21 SIGTTIN      Background read from tty (POSIX).
        22 SIGTTOU      Background write to tty (POSIX).
        23 SIGURG       Urgent condition on socket (4.2 BSD).
        24 SIGXCPU      CPU limit exceeded (4.2 BSD).
        25 SIGXFSZ      File size limit exceeded (4.2 BSD).
        26 SIGVTALRM    Virtual alarm clock (4.2 BSD).
        27 SIGPROF      Profiling alarm clock (4.2 BSD).
        28 SIGWINCH     Window size change (4.3 BSD, Sun).
        29 SIGPOLL      Pollable event occurred (System V).
        29 SIGIO        I/O now possible (4.2 BSD).
        30 SIGPWR       Power failure restart (System V).
        31 SIGSYS       Bad system call.

CODES
}


#------------------------------------------------------------------------------
#  Main Line  -----------------------------------------------------------------
#------------------------------------------------------------------------------

    die("! $ownName: too many args starting with: '$ARGV[3]'\n") 
      if ($ARGV[3]);

        $op = $ARGV[0] if ($ARGV[0]);
      $code = $ARGV[1] if ($ARGV[1]);
    $usrMsg = $ARGV[2] if ($ARGV[2]);


#-------------------------------+
# Select the Exit option.	|
#-------------------------------+

    if (not $op)
      {
        print(STDERR 
              "\tEnter one of the following options:\n\n",
              "\tc - exit with a specified status code (integer)\n",
              "\te - exit with a specified status code and error message\n",
              "\to - exit with a specified status code and STDOUT text\n",
              "\ti - die with a specified interrupt signal\n\n",
              "\t\toption> "
             );
        $op = <STDIN>;
        chomp($op);
      }

    $op =~ s/^\s+|\s+$//g;		# Trim leading and trailing spaces.

    die("! $ownName: use one of [ceoi] for first arg\n") 
      if ($op !~ m/[ceoi]/);


#-------------------------------+
# Get the code/signal to use.	|
#-------------------------------+

    if (not $code)
      {
        showSigCodes() if ($op eq "i");
        print(STDERR "\t\t", ($op eq "i") ? "signal> " : "status> ");
        $code = <STDIN>;
        chomp($code);
        $code =~ s/^\s+|\s+$//g;
      }

    die("! $ownName: '$code' is not an integer\n") if ($code !~ m/^[+-]?\d+$/);


#-------------------------------+
# Say good night Dick.		|
#-------------------------------+

    if ($op eq "i")
      {
        print(STDERR "$ownName: killing myself with '$code' signal\n");
        kill($code,0);
        print(STDERR "Process has been resurrected after signal!\n");
      }
    elsif ($op =~ m/[ceo]/)
      {
        if ($op eq "e")
          {
            print(STDERR "$ownName: exiting with status '$code'\n$usrMsg\n");
          }
        elsif ($op eq "o")
          {
            print("$ownName: exiting with status '$code'\n$usrMsg\n");
          }
        exit($code);
        print(STDERR "Huh!?\n");
      }

    warn("! $ownName: exiting with 0 status\n");
    exit 0;


#==[ EOF: bail-out.pl ]========================================================